ToolStrip, rendering in stile Xp!

Ecco una semplice classe per dare alle ToolStrip uno style Xp-Like (di colore rosso!).
E' soltanto un punto di partenza, Può essere arricchita riscrivendo i metodi che si
occupano del disegno delle tendine piuttosto che dei bottoni..

Class bcc_XpRenderer
Inherits ToolStripProfessionalRenderer

Protected Overrides Sub OnRenderToolStripBackground( _
ByVal e As System.Windows.Forms.ToolStripRenderEventArgs)

  Dim r1, r2, r3 As Rectangle
  Dim b1, b3 As Drawing2D.LinearGradientBrush

  r1 = New Rectangle(0, 0, e.ToolStrip.Width, 10)
  r2 = New Rectangle(0, 10, e.ToolStrip.Width,  e.ToolStrip.Height - 10)
  r3 = New Rectangle(0, e.ToolStrip.Height - 10, e.ToolStrip.Width, 10)

  b1 = New Drawing2D.LinearGradientBrush(r1, _
  Color.White, _
  Color.Red, _
  Drawing2D.LinearGradientMode.Vertical)

  b3 = New Drawing2D.LinearGradientBrush(r3, _
  Color.Red, _
  Color.DarkRed, _
  Drawing2D.LinearGradientMode.Vertical)

  e.Graphics.FillRectangle(b1, r1)
  e.Graphics.FillRectangle(Brushes.Red, r2)
  e.Graphics.FillRectangle(b3, r3)

  b1.Dispose()
  b3.Dispose()

End Sub

End Class

Per vedere l'effetto che fa basterà impostare la proprietà Renderer del Toolstrip con new bcc_XpRenderer() ed il gioco è fatto.

Testare la connessione alla rete..

Vogliamo sapere se disponiamo di una connessione alla rete?
Ecco cosa ci consiglia il prezioso MSDN..
http://msdn2.microsoft.com/it-it/library/4y6b9c17(VS.80).aspx

mi verrebbe da dire: ci sei, ce la fai? sei connesso???
.. oops l'ho detto.. :D

Windows Form e InputValidation

Ecco un piccolo esempio su come, generalmente, gestisco la validazione dei dati. Immaginiamo di avere un form che implementi una ipotetica scheda clienti con i seguenti campi: nome, cognome, indirizzo e numero telefonico. L'utente deve inserire necessariamente i primi tre campi e se inserisce anche il numero di telefono deve inserirlo ovviamente in un formato corretto. Se qualche campo viola le condizioni precedenti, il bottone per salvare i dati sul database viene disabilitato e accanto a quei campi che contengono dati non validi compare un messaggio di errore. Ingredienti: un form, 4 controlli TextBox accompagnati da altrettanti controlli Label, un controllo Button per il salvataggio dei dati, un ErrorProvider per i messaggi di errori e, infine, la piccolissima classe bcc_InputValidation che incontreremo tra qualche riga. Validare ogni controllo singolarmente è semplice, in questo esempio avendo solamente dei TextBox si sfrutta per questo scopo l'evento TextChanged. Sarebbe stato più corretto utilizzare l'evento Validating ma avremmo visto il risultato della validazione solo dopo essere usciti dal controllo, usando invece l'evento TextChanged avremo una validazione in tempo reale. La cosa più antipatica è invece il dover tenere traccia dello stato di tutti i controlli per decidere quando abilitare il bottone per il salvataggio. La classe bcc_InputValidation si occupa proprio di questo:

Private Class bcc_InputValidation

Private mht As New Hashtable

' serve ad indicare che la proprietà InputValido è cambiata
Public Event InputValidoChanged As EventHandler

' salva lo stato di ogni controllo che vogliamo monitorare
Public Sub SettaStato(ByVal str_NomeControllo As String,ByVal bool_Valido As Boolean)

If mht.ContainsKey(str_NomeControllo)  Then

 mht(str_NomeControllo) = bool_Valido

Else

 mht.Add(str_NomeControllo, bool_Valido)

End If

' è cambiato il valore di InputValido
RaiseEvent InputValidoChanged(Me,New EventArgs)

End Sub

' Restituisce True se tutti i controlli sono validi
Public ReadOnly Property InputValido()
Get
   Dim val As Boolean

   For Each val In mht.Values

    ' se trova un solo controllo non valido, restituisce False
    If Not val Then Return False

   Next

   ' Tutti i controlli sono validi
   Return True

End Get

End Property

End Class

La proprietà Enabled del bottone ( btn_Salva ) che serve al salvataggio dei dati, viene messa in DataBinding con la proprietà InputValido dell'oggetto globale mInputValidation, istanza della classe bcc_InputValidation. Ovviamente, quando InputValido vale True il bottone verrà automaticamente abilitato, di contro, quando InputValido vale False il bottone verrà disabilitato. Vediamo un pò più nel dettaglio il funzionamento della classe bcc_InputValidation. Ogni volta che si esegue la validazione di un singolo controllo, si memorizza l'esito della validazione ( true o false ) nella HashTable della classe bcc_InputValidation attraverso il metodo SettaStato il quale poi si occuperà di lanciare un evento InputValidoChanged. E' proprio questo evento
che notifica al Databinding il cambiamento della proprietà pubblica InputValido determinando così lo stato ( abilitato o meno ) del bottone btn_Salva. Ecco il resto del codice:

Private Sub frmMain_Load(ByVal sender As Object,_
ByVal e As System.EventArgs) Handles Me.Load

' questa inizializzazione fa scattare l'input validation
txt_Cognome.Text = "..."
txt_Nome.Text = "..."
txt_Indirizzo.Text = "..."
txt_Telefono.Text = ""

' se tutti i controlli sono validi,
' il bottone salva viene abilitato
btn_Salva.DataBindings.Add("Enabled", mInputValidation, "InputValido")

End Sub

Private Sub btn_Salva_Click(ByVal sender As Object, _
ByVal e As System.EventArgs) Handles btn_Salva.Click

' ....
' qui vanno le chiamate al database
' ...

MsgBox("dati salvati correttamente")

End Sub

Private Sub txt_TextChanged(ByVal sender As Object, _
ByVal e As System.EventArgs) Handles txt_Nome.TextChanged

Dim txt As TextBox = sender

' per default setta lo stato del controllo a valido
mInputValidation.SettaStato(txt.Name, True)
ep_ErrorProvider.SetError(txt, "")

If txt.Text.Trim = "" Then

mInputValidation.SettaStato(txt.Name, False)
ep_ErrorProvider.SetError(txt, "campo richiesto!")

End If

End Sub

Private Sub txt_Telefono_TextChanged(ByVal sender As Object, _
ByVal e As System.EventArgs) Handles txt_Telefono.TextChanged

mInputValidation.SettaStato("txt_Telefono", True)
ep_ErrorProvider.SetError(txt_Telefono, "")

' non è un campo richiesto
If txt_Telefono.Text.Trim = "" Then Exit Sub

' se l'utente ha inserito il telefono, validiamolo
If Not Regex.IsMatch(txt_Telefono.Text.Trim, "^[+]?[0-9 ]+$") Then

mInputValidation.SettaStato("txt_Telefono", False)
ep_ErrorProvider.SetError(txt_Telefono, "formato non valido!")

End If

End Sub

A questo link il progetto completo.

Un Editor HTML per vb.net

Qualche giorno fa mi sono imbattuto nel seguente problema: dovevo scrivere una applicazione Windows Form che permettesse all'utente di inviare delle email in formato html. Per l'invio delle email nessun problema, qualche problema poteva nascere dal fatto che l'utente dovesse formattarle in html. Mi sarebbe servito quindi un editor html WYSIWYG in quanto gli utenti, per definizione, non conoscono l'html.. Li per li ho pensato che il compito fosse di immediata soluzione, "scarico qualche controllo per vb.net ed il gioco è fatto", mi sono detto. Mi sono messo allora al lavoro cercando in rete qualche cosa che potesse tornare utile al mio scopo, ma la maggior parte dei controlli che ho trovato erano o a pagamento o troppo complicati da riutilizzare. Non mi sono perso d'animo e, rimboccandomi le maniche, ho deciso di fare tutto da me. Una base dalla quale partire l'avevo già, qualche anno fa mi ero infatti cimentato nella scrittura di un editor html per asp.net, dovevo quindi importare questo controllo in vb.net. Ecco come ho risolto il problema: ho utilizzato un controllo WebBrowser da fare puntare alla pagina html contenente l'editor. A questo punto il grosso del lavoro era stato fatto, e anche in pochissimo tempo, per completare l'opera dovevo solo dare un aspetto più gradevole all'editor, questa pagina html conteneva infatti, nella sua parte alta, una toolbar per la formattazione del testo che non si integrava bene con il resto dell'applicazione. Ho deciso allora di lasciare nella pagina html solo il cuore javascript dell'editor e di implementare la bottoniera "all'esterno" del WebBrowser usando due controlli ToolStrip. La comunicazione tra l'interfaccia grafica e il javascript della pagina è stata realizzata attraverso la proprietà ObjectForScripting del controllo WebBrowser. Utilizzando il metodo WebBrowser.Document.InvokeScript è possibile richiamare una procedura javascript definita all'interno del documento html, di contro, si può invocare una procedura vb.net dal javascript utilizzando la sintassi window.external.nomeprocedura.
Ecco uno screenshot dell'editor



Al solito, un esempio vale più di mille parole, a questo link potrete trovare una soluzione contenente il codice sorgente dell'editor html. Per chi volesse saperne di più sulla proprietà ObjectForScripting del controllo WebBrowser ecco il link alla pagina di msdn

un filtro veloce..

Quando mi capita di realizzare qualche gestionale, la richiesta che mi sento fare di più dai clienti è quella di poter lavorare senza staccare le mani dalla tastiera.. odiano il mouse. Per far fronte a tale richiesta, qualche tempo fa, ho realizzato uno UserControl facilmente riadattabile che permette la ricerca e la selezione di elementi ( ad esempio clienti, articoli etc etc ) all'interno di una DataGridView in modo molto rapido.

Nell'immagine qui in alto possiamo vedere una lista di clienti filtrata per "Codice Cliente" e "Nome Cliente". Mentre si digitano le parole chiave con le quali filtrare l'elenco di clienti, è possibile muoversi all'interno dell'elenco filtrato usando le freccie su e giù senza dover spostare il focus sulla DataGridView. A questo link potrete scaricare una soluzione vb.net 2005 contenente il codice delle UserControl. Qui brevemente mi limiterò ad illustrare le idee sulle quali si basa il filtro. Le due caselle di testo "Codice Cliente" e "Nome Cliente" sono il cuore del filtro, attraverso di esse si deve poter filtrare i clienti e contestualmente muoversi all'interno dell'elenco filtrato. Per ora puntiamo la nostra attenzione sulla parte di scorrimento e selezione del filtro. Entrambe le sopracitate caselle di testo sono istanze della classe bcc_TextBox, una classe che eredita da TextBox La classe bcc_TextBox contiene l'override della funzione ProcessCmdKey attraverso la quale è possibile intercettare la pressione di ogni tasto all'interno del controllo TextBox. I tasti che ci interessa intercettare e gestire sono ovviamente i tasti freccia SU e GIU e il tasto INVIO, per tutti gli altri vogliamo che la classe bcc_TextBox si comporti come un normale TextBox. Ecco il frammento di codice qui di seguito:

Protected Overrides Function ProcessCmdKey(ByRef msg As System.Windows.Forms.Message, ByVal keyData As System.Windows.Forms.Keys) As Boolean

Select Case keyData

Case Keys.Down, Keys.Up, Keys.Return, Keys.Enter

RaiseEvent OneKeyPressed(keyData)
Return True

Case Else

Return MyBase.ProcessCmdKey(msg, keyData)

End Select

End Function

Come si può vedere dal codice, la classe bcc_TextBox lancia un evento OneKeyPressed per notificare all'esterno l'avvenuta pressione di uno dei tasti che si vuole gestire passando come parametro proprio il codice del tasto premuto. Sarà poi lo UserControl che si occuperà di gestire l'evento in questione attraverso il seguente handler:

Private Sub m_OneKeyPressed(ByVal key As System.Windows.Forms.Keys)

If IsNothing(dgv_Clienti.DataSource) Then Exit Sub

Dim cm As CurrencyManager
cm = Me.BindingContext(dgv_Clienti.DataSource)


If cm.Position = -1 Then Exit Sub

Select Case key

Case Keys.Up

If cm.Position = 0 Then
cm.Position = cm.List.Count - 1
Else
cm.Position -= 1
End If


Case Keys.Down

If cm.Position = cm.List.Count - 1 Then
cm.Position = 0
Else
cm.Position += 1
End If

Case Keys.Return, Keys.Enter

m_SelezionaCliente()

End Select

End Sub

Per spostarsi tra le righe del DataGridView si è usato un CurrencyManager, sfruttandone la proprietà Position è semplicissimo muoversi tra l'elenco filtrato dei clienti . Il CurrencyManager viene anche impiegato per restituire il cliente selezionato.

Private Sub m_SelezionaCliente()

Dim drv As DataRowView
Dim cm As CurrencyManager

cm = Me.BindingContext(dgv_Clienti.DataSource)
If cm.Position = -1 Then Exit Sub

drv = CType(cm.Current, DataRowView)

RaiseEvent ClienteSelezionato(drv("Id"), drv("Nome"))

End Sub

Resta da spiegare come avviene il filtraggio dei dati. Nessuna particolare novità, si è settato un evento TextChanged sulle due caselle di testo e si è composta una stringa con la quale filtrare il DataView usato come DataSource del DataGridView

Private Sub txt_DoFilter(ByVal sender As System.Object, ByVal e As System.EventArgs)

Try
RemoveHandler txt_CodiceCliente.TextChanged, AddressOf txt_DoFilter
RemoveHandler txt_NomeCliente.TextChanged, AddressOf txt_DoFilter

Dim dv As DataView
Dim strFilter As String = ""

dv = dgv_Clienti.DataSource

strFilter = ""

If txt_CodiceCliente.Text.Trim <> "" Then

Dim val As Int64

Try

val = CInt(txt_CodiceCliente.Text.Trim)

Catch ex As Exception

txt_CodiceCliente.Text = ""

Finally

strFilter = "( Id = " & txt_CodiceCliente.Text.Trim & " )"

End Try

End If

If txt_NomeCliente.Text.Trim <> "" Then

Dim tmp As String

tmp = txt_NomeCliente.Text.Trim
tmp = tmp.Replace("'", "")
tmp = tmp.Replace("""", "")
tmp = tmp.Replace("%", "")

If tmp <> txt_NomeCliente.Text.Trim Then txt_NomeCliente.Text = tmp

strFilter &= IIf(strFilter <> "", " AND ", "") & "(Nome Like '%" & txt_NomeCliente.Text.Trim & "%')"

End If

dv.RowFilter = strFilter
lb_ClientiTrovati.Text = dgv_Clienti.RowCount

Catch ex As Exception

Finally

AddHandler txt_CodiceCliente.TextChanged, AddressOf txt_DoFilter
AddHandler txt_NomeCliente.TextChanged, AddressOf txt_DoFilter

End Try

End Sub

printf("Hello World!..\n");

di tanto in tanto posterò qui qualche semplice soluzione
( trovata rigorosamente sotto l'effetto di litri e litri di caffè )
ai più comuni problemi di programmazione, con la speranza di
poter essere di aiuto a qualche altro caffeinomane..